home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / slots.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1984-04-24  |  4.7 KB  |  150 lines
  1. 5  M=25
  2. 10  RANDOMIZE INT(VAL(MID$(TIME$,7,2)))
  3. 15  CLS:GOSUB 1000
  4. 18  REM 'CONVERTED FOR IBM-PC FROM 101 BASIC COMPUTER GAMES BY DIGITAL
  5. 20  REM 'EQUIPMENT CORP. SUBMITTED TO DIGITAL BY ROB HOFFBERG OF ROSLYN N.Y.
  6. 25  REM 'AUTHOR UNKNOWN
  7. 30  CLS
  8. 32  PRINT "OK ";N$;" Here are the odds:"
  9. 35  LOCATE 5,10:PRINT "SYMBOL     HOW MANY     PAYOUT"
  10. 36  LOCATE 6,10:PRINT "111111111111111111111111111111"
  11. 38  LOCATE 7,10:PRINT "CHERRY        3         $2.00"
  12. 39  LOCATE 8,10:PRINT "CHERRY        2         $1.00   LEFT & MID WINDOWS ONLY!"
  13. 40  LOCATE 9,10:PRINT "CHERRY        1         $0.50   LEFT WINDOW ONLY!"
  14. 41  LOCATE 11,10:PRINT "PLUM          3         $5.00"
  15. 42  LOCATE 12,10:PRINT "ORANGE        3         $7.50"
  16. 43  LOCATE 13,10:PRINT "*BAR*         3        $10.00"
  17. 44  LOCATE 15,10:PRINT "      LEMONS ALWAYS LOOSE"
  18. 45  LOCATE 20,5:PRINT "When the message PULL appears, press ENTER to PULL."
  19. 46  LOCATE 21,5:PRINT "Or type END to end the session."
  20. 47  LOCATE 23,5:PRINT "When you are ready to begin press ENTER.";:INPUT Z9$
  21. 110  L$=CHR$(186)
  22. 120  S$=CHR$(205)
  23. 130  B$=CHR$(186)
  24. 131  DIM W$(4)
  25. 132  W$(1)="CHERRY":W$(2)="      ":W$(3)="*BAR* ":W$(4)=" PLUM "
  26. 133  REM "WHEEL ONE
  27. 134  DIM V$(7)
  28. 135  V$(1)="ORANGE":V$(2)=" PLUM ":V$(3)="LEMON ":V$(4)="*BAR* "
  29. 136  V$(7)="CHERRY":V$(5)="CHERRY":V$(6)="CHERRY"
  30. 137  REM "WHEEL TWO
  31. 138  DIM V1$(7)
  32. 139  V1$(1)="*BAR* ":V1$(2)="LEMON ":V1$(3)=" PLUM "
  33. 140  V1$(4)="CHERRY":V1$(5)=" PLUM ":V1$(6)="ORANGE":V1$(7)="CHERRY"
  34. 141  REM "WHEEL THREE
  35. 142  DIM V3$(5)
  36. 143  V3$(1)=" PLUM ":V3$(2)="*BAR* ":V3$(3)="CHERRY":V3$(4)="LEMON "
  37. 144  V3$(5)="ORANGE"
  38. 200  CLS
  39. 210  Y=16:FOR X=1 TO 18:LOCATE X,Y:PRINT S$:NEXT X
  40. 215  X=18:FOR Y=17 TO 50:LOCATE X,Y:PRINT B$:NEXT Y
  41. 220  Y=51:FOR X=18 TO 1 STEP-1:LOCATE X,Y:PRINT S$:NEXT X
  42. 225  X=1:FOR Y=50 TO 17 STEP-1:LOCATE X,Y:PRINT L$:NEXT Y
  43. 230  REM "ARM
  44. 234  LOCATE 14,52:PRINT "/";
  45. 235  Y=52:FOR X=13 TO 8 STEP-1:LOCATE X,Y:PRINT "//";:Y=Y+1:NEXT X
  46. 240  FOR X=7 TO 6 STEP-1:LOCATE X,57:PRINT STRING$(3,196):NEXT X
  47. 255  LOCATE 13,28:PRINT "P A Y O U T":LOCATE 14,33
  48. 260  X=15:FOR Y=24 TO 42:LOCATE X,Y:PRINT L$:NEXT Y
  49. 265  FOR X=15 TO 17:LOCATE X,43:PRINT S$:NEXT X
  50. 270  FOR Y=42 TO 24 STEP-1:LOCATE 17,Y:PRINT B$:NEXT Y
  51. 275  FOR X=17 TO 15 STEP-1:LOCATE X,23:PRINT S$:NEXT X
  52. 279  REM "******LEFT WINDOW*****
  53. 280  FOR Y=18 TO 26:LOCATE 5,Y:PRINT L$:NEXT Y
  54. 285  FOR X=5 TO 7:LOCATE X,27:PRINT S$:NEXT X
  55. 290  FOR Y=26 TO 18 STEP-1:LOCATE 7,Y:PRINT B$:NEXT Y
  56. 300  FOR X=7 TO 5 STEP-1:LOCATE X,18:PRINT S$:NEXT X
  57. 305  REM "*****MID WINDOW*****
  58. 310  FOR Y=30 TO 37:LOCATE 5,Y:PRINT L$:NEXT Y
  59. 315  FOR X=5 TO 7:LOCATE X,38:PRINT S$:NEXT X
  60. 320  FOR Y=37 TO 30 STEP-1:LOCATE 7,Y:PRINT B$:NEXT Y
  61. 325  FOR X=7 TO 5 STEP-1:LOCATE X,29:PRINT S$:NEXT X
  62. 330  REM "*****RIGHT WINDOW*****
  63. 335  FOR Y=41 TO 48:LOCATE 5,Y:PRINT L$:NEXT Y
  64. 340  FOR X=5 TO 7:LOCATE X,49:PRINT S$:NEXT X
  65. 345  FOR Y=48 TO 41 STEP-1:LOCATE 7,Y:PRINT B$:NEXT Y
  66. 350  FOR X=7 TO 5 STEP-1:LOCATE X,40:PRINT S$:NEXT X
  67. 355  REM "DO YOU PULL OR END
  68. 356  LOCATE 21,24:PRINT "YOU NOW HAVE ";:PRINT USING "$$###.##";M
  69. 357  LOCATE 22,30:PRINT "PULL/END";:INPUT A$
  70. 358  LOCATE 16,24:PRINT E$;E$;E$;E$;"   "
  71. 359  E$="    ":LOCATE 6,19:PRINT E$;E$:LOCATE 6,30:PRINT E$;E$:LOCATE 6,41:PRINT E$;E$
  72. 360  IF A$="end" OR LEFT$(A$,1)="e" OR A$="END" OR LEFT$(A$,1)="E" THEN GOTO 900
  73. 373  REM " * PICK THE WHEELS
  74. 375  FOR I=1 TO 2:Z(I)=INT((RND*7)+1):NEXT I
  75. 376  Z(3)=INT((RND*5)+1)
  76. 400  REM "***** ROLL ALL WINDOWS AND PICK LEFT *****
  77. 410  FOR X=1 TO 10:FOR Y=1 TO 4:LOCATE 6,20:PRINT W$(Y)
  78. 411  LOCATE 6,31:PRINT W$(Y):LOCATE 6,42:PRINT W$(Y):NEXT Y:NEXT X
  79. 415  LOCATE 6,20:PRINT V$(Z(1))
  80. 418  SOUND 200,2
  81. 419  REM " ***** ROLL MID AND RIGHT AND PICK MID *****
  82. 420  FOR X=1 TO 15:FOR Y=1 TO 4
  83. 421  LOCATE 6,31:PRINT W$(Y):LOCATE 6,42:PRINT W$(Y):NEXT Y:NEXT X
  84. 425  LOCATE 6,31:PRINT V1$(Z(2))
  85. 429  SOUND 200,2
  86. 430  REM "***** ROLL RIGHT AND PICK RIGHT *****
  87. 435  FOR X=1 TO 20:FOR Y=1 TO 4
  88. 437  LOCATE 6,42:PRINT W$(Y):NEXT Y:NEXT X
  89. 439  LOCATE 6,42:PRINT V3$(Z(3))
  90. 500  SOUND 200,2
  91. 501  REM "DO I HAVE 3 OF A KIND
  92. 505  IF V$(Z(1))<>V1$(Z(2)) THEN 530
  93. 510  IF V1$(Z(2))<>V3$(Z(3)) THEN 530
  94. 514  IF V$(Z(1))<>"CHERRY" THEN 516
  95. 515  LOCATE 16,27:PRINT "YOU WIN $2.00":M=M+2:GOTO 355
  96. 516  IF V$(Z(1))<>" PLUM " THEN 518
  97. 517  LOCATE 16,27:PRINT "YOU WIN $5.00":M=M+5:GOTO 355
  98. 518  IF V$(Z(1))<>"ORANGE" THEN 520
  99. 519  LOCATE 16,27:PRINT "YOU WIN $7.50":M=M+7.5:GOTO 355
  100. 520  IF V$(Z(1))<>"*BAR* " THEN 522
  101. 521  LOCATE 16,27:PRINT "YOU WIN $10.00":M=M+10:GOTO 355
  102. 522  REM "LEMONS
  103. 523  LOCATE 16,28:PRINT "LEMONS LOSE!":M=M-0.25:GOTO 355
  104. 529  REM
  105. 530  REM "DO I HAVE CHERRIES
  106. 535  IF V$(Z(1))<>"CHERRY" THEN 600
  107. 540  IF V1$(Z(2))<>"CHERRY" THEN 575
  108. 544  REM
  109. 545  REM "2 CHERRIES
  110. 546  LOCATE 16,27:PRINT "YOU WIN $1.00":M=M+1:GOTO 355
  111. 574  REM
  112. 575  REM " 1 CHERRY
  113. 576  LOCATE 16,27:PRINT "YOU WIN $0.50":M=M+0.5:GOTO 355
  114. 600  REM
  115. 601  REM " GOT SCHMALTZ
  116. 602  ON Z(3) GOSUB 605,606,607,608,609,610,611
  117. 604  M=M-0.25:GOTO 355
  118. 605  LOCATE 16,25:PRINT "TRY BINGO INSTEAD":RETURN
  119. 606  LOCATE 16,25:PRINT "HA HA YOU LOSE":RETURN
  120. 607  LOCATE 16,25:PRINT "ZILCH-O":RETURN
  121. 608  LOCATE 16,25:PRINT "TRY AGAIN SUCKER":RETURN
  122. 609  LOCATE 16,25:PRINT "TRY VEGAS INSTEAD":RETURN
  123. 610  LOCATE 16,25:PRINT "YOU GOT SCHMALTZ":RETURN
  124. 611  LOCATE 16,25:PRINT "BACK TO STAR TREK":RETURN
  125. 900  LOCATE 16,26:PRINT "BYE-BYE ";N$
  126. 994  A$=INKEY$:IF A$="" THEN GOTO 994
  127. 995  END
  128. 999  END
  129. 1000  'COLOR 3
  130. 1010  KEY OFF:CLS:GOTO 1030
  131. 1020  CLS
  132. 1030  FOR J=2 TO 22
  133. 1040  LOCATE 2,2:PRINT CHR$(201):LOCATE 2,79:PRINT CHR$(187)
  134. 1050  LOCATE 23,2:PRINT CHR$(200):LOCATE 23,79:PRINT CHR$(188)
  135. 1060  LOCATE J,2:PRINT CHR$(186)
  136. 1070  LOCATE J,79:PRINT CHR$(186)
  137. 1080  NEXT J
  138. 1090  FOR J=3 TO 78
  139. 1100  LOCATE 2,J:PRINT CHR$(205)
  140. 1110  LOCATE 23,J:PRINT CHR$(205)
  141. 1120  NEXT J
  142. 1130  'COLOR 2
  143. 1140  LOCATE 4,4:PRINT "W E L C O M E  T O . . ."
  144. 1150  LOCATE 8,30:PRINT "I B M ' S  C A S I N O"
  145. 1160  LOCATE 17,4:PRINT "Today you will lose your money at IBM's famous slot machine."
  146. 1170  LOCATE 18,4:PRINT "You have been given a credit line of $25.00. Therefore at 25 a pull you"
  147. 1180  LOCATE 19,4:PRINT "have a minimum of 100 pulls!"
  148. 1190  LOCATE 20,4:PRINT "By the way what is your name";:INPUT N$
  149. 1200  RETURN
  150.